Kleintierhaltung

Aufgabe:

In einem Stall gibt es Kaninchen (x) und Hühner (y).
Man zählt 20 Köpfe (k) und 56 Beine (b)

  1. Man berechne x und y.
  2. Welche anderen Vorgaben für k (Köpfe) und b (Beine) sind denkbar (bis zu einer gewissen Obergrenze)?

Programmcode für Teilaufgabe (1):

g1:x+y=20;
g2:4*x+2*y=56;
l:solve([g1,g2],[x,y]);

Maxima Online: http://maxima-online.org/?inc=r-295002031

Programmcode für Teilaufgabe (2):

Triviale Lösung mit Vielfachen (nun mit x Hühnern und y Kaninchen):

f(k,b):=solve([x+y=k,2*x+4*y=b],[x,y]);
f(20,56);
f(40,112);

Es scheint viele Lösungen zu geben: http://maxima-online.org/?inc=r1375203649
(das „ruft“ nach weiteren Untersuchungen).

 

 

Zum Thema Nachfragefunktion

Eine Nachfragefunktion beschreibt den Zusammenhang der nachgefragten Menge (abhängige Variable x) mit dem Preis (unabhängige Variable p). Es wird häufig das normale Nachfragegesetz unterstellt: steigt der Preis, sinkt die Nachfrage und umgekehrt. Eine bekannte Ausnahme ist der Snobeffekt. Die Nachfragefunktion entspricht (irgendwie) dem Verhalten der Konsument/inn/en.

Achtung: Normalerweise wird die unabhängige Variable auf der Abszissenachse und die abhängige Variable auf der Ordinatenachse abgetragen. Bei der Nachfragepunktion hat es sich in anders eingebürgert: p=p(x) statt x = x(p)

1. Aufgabe: Lineare Nachfragefunktion

Eine lineare Nachfragefunktion ist durch zwei Punkte gegeben.

nachfrage

Programcode:

x1:0;p1:5;
x2:10;p2:0;
g:p=a*x+b;
g1:g,x=x1,p=p1;
g2:g,x=x2,p=p2;
l:solve([g1,g2],[a,b]);
Nachfragefunktion:g,l;

Erklärung:

lf1

  1. Die Preisobergrenze (der Höchstpreis) ist 5 GE, da ist dann die Nachfrage auf 0 ME gesunken.
  2. Wenn man das Produkt verschenkt, werden 10 ME nachgefragt. Das ist die Sättigungsmenge.
  3. Ansatz für eine lineare Nachfragefunktion.
  4. Koordinaten des ersten Punktes einsetzen.
  5. Koordinaten des zweiten Punktes einsetzen.
  6. Das Gleichungssystem nach den unbekannten Koeffizienten auflösen.
  7. Die gefundenen Koeffizienten in die Nachfragefunktion einsetzen.

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r701159078

2. Aufgabe: Lineare Nachfragefunktion

Die Marktforschung für eine Ware ergab, dass der
Monatsumsatz bei einem Verkaufspreis von p1 €
x1 ME, bei p2 € nur noch x2 ME betrug.
Wie groß ist der Absatz x3 bei einem Stückpreis
von p3 € ?

Programmcode:

p1:1;x1:1000;
p2:2;x2:900;
p3:3;
g(p,x):=p=a*x+b;
g1:g(p1,x1);
g2:g(p2,x2);
l:algsys([g1,g2],[a,b]);
A:a,l[1][1];
B:b,l[1][2];
Nachfrage:p=A*x+B;
g:solve(Nachfrage,x);
Absatz:x,g[1];
x3:ev(Absatz,p=p3);
print("Der gesuchte Absatz ist",x3);

 Lösung mit Maxima Online: http://maxima-online.org/?inc=r749682105

3. Aufgabe: Quadratische Nachfragefunktion

Von einer quadratischen Nachfragefunktion ist bekannt:

a) bei einem Preis von 3€ können 1000 Stück verkauft werden,
b) bei einem Preis von 1€ können 3000 Stück verkauft werden und
c) die Sättigungsmenge beträgt 5000 Stück!

Man ermittle diese Funktion und zeichne diese mit Geogebra!

Programmcode:

x1:1000$p1:3$
x2:3000$p2:1$
x3:5000$p3:0$
g(x,p):=p=a*x**2+b*x+c;
g1:g(x1,p1);
g2:g(x2,p2);
g3:g(x3,p3);
k:solve([g1,g2,g3],[a,b,c]);
Nachfrage:g(x,p),k;
p:rhs(Nachfrage);
p(x):=''p
/** Das ist die gesuchte Nachfragefunktion */;
plot2d([p(x)], [x,0,5200])$

Die „$“ Zeichen (Echo-Unterdrückung) sind nur in wxMaxima wirksam. Maxima Online macht „;“ daraus.

Ausführung mit Maxima Onlinehttp://maxima-online.org/?inc=r-1930608879

Die Funktion soll auch mit Geogebra gezeichnet werden!

S-förmiger Kostenverlauf

Begriffserklärung:
Eine Kostenfunktion stellt (innerhalb der Wirtschaftswissenschaften) eine eindeutige Zuordnung der Kosten K(x) zu einer Bezugsgröße x  dar.
Unsere Bezugsgröße ist meistens die Produktionsmenge in ME (Mengenheiten, z.B. Stück).
Ein s-förmiger Kostenverlauf (zuerst degressiv und nach der Kostenkehre progressiv) lässt sich aus dem Gesetz vom abnehmenden Grenzertrag herleiten. Die praktische Anwendbarkeit wird allerdings angezweifelt.

Ausgangssituation:

In den Mathematiklehrbüchern werden bei den Aufgaben der Kosten- und Preistheorie häufig Funktionen vorgegeben. Zur Theorie passende Funktionen muss man aber erst einmal finden.
Hier hilft Geogebra: http://www.geogebratube.org/student/m108070
Erklärung zur „Konstruktion“:sfkk_konstruktionDurch Ziehen an den Punkten kann man die Aufgabenstellungen einfach verändern.
Man kann die Geogebra-Datei für die lokale Verwendung herunterladen: http://www.geogebratube.org/material/download/format/file/id/108070

Aufgaben für die Lösung mit Maxima:

  1. Man bestimme die Kostenfunktion aus den Punkten A,B,C und D.
  2. Man bestimme die Fixkosten.
  3. Man bestimme die Kostenkehre.
  4. Man bestimme das Betriebsoptimum.
  5. Man bestimme die langfristige Preisuntergrenze.

Ein ungewöhnlicher Programmcode zur Bestimmung der Kostenfunktion:Berechnung von PolynomfunktionenWenn in Zeile (1) zwei Punkte gegebenen sind, erhält man eine lineare, bei drei Punkten eine quadratische und bei vier Punkten eine kubische Kostenfunktion. Um die kubische Kostenfunktion geht es beim s-förmigen Kostenverlauf.

Erklärung, wie das Programm Nr. 1 welches nicht nur für kubische, sondern auch für lineare und quadratische Kostenfunkitonen geeignet ist, funktioniert:

  1. Eingabe der gegebenen Punkte in Listenform.
  2. Da zwei, drei oder vier Punkte sinnvoll sein können, muss das Programm prüfen, wie viele Punkte gegeben sind.
  3. Der Grad des Polynoms ist um eins niedriger als die Anzahl der Punkte.
  4. Hier  wird ein raffinierter Ansatz verwendet.
    g(x) ist eine Funktion mit einem Punkt x:[x[1],x[2]] als Argument.
    Die Obergrenze der Summation muss n-1 = Grad und nicht n sein, da sonst der unbestimmte Fall 0^0 auftreten könnte. Dafür einfach a[n] ausserhalb hinzufügen.
  5. Die zwei, drei oder vier Gleichungen werden automatisch mit map erzeugt.
  6. Wie wir in (4) bemerkt haben, sind die unbekannten Koeffizienten nicht a,b,c,… sondern a[1],a[2],…,a[n].
  7. Die Lösungsmenge des Gleichungssystems wird ermittelt.
  8. Mit Hilfe der Skalarmultiplikation von Vektoren (Listen) wird die Kostenfunktion berechnet und ausgegeben.

Lösungen mit Maxima-Online unter Verwendung eines früheren Programms: https://casmaxima.wordpress.com/2014/04/08/ein-polynom-zur-einer-gegebenen-punkteliste-bestimmen/

  1. http://maxima-online.org/?inc=r-1197448632
  2. http://maxima-online.org/?inc=r-375516577
  3.  http://maxima-online.org/?inc=r-32032642
  4. http://maxima-online.org/?inc=r1686026510
  5. http://maxima-online.org/?inc=r1686026510

 

Ziffernsumme einer dreistelligen Zahl

Eine Aufgabenstellung bei www.edhelper.com lautete in deutscher Übersetzung:
(g1) Die Ziffernsumme einer dreistelligen Zahl ist 18
(g2) Die Hunderterstelle ist um 6 größer als das 2fache der Zehnerstelle
(g3) Die Einerstelle ist um 6 größer als das 3fache der Zehnerstelle
Die dreistellige Zahl ist gesucht.

Programmcode:

g1:H+Z+E=18;
g2:H-6=2*Z;
g3:E-6=3*Z;
l:solve([g1,g2,g3],[H,Z,E]);
Zahl:100*H+10*Z+E,l;

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r-144388483

Übungsauftrag:

Zweiergruppen:
Formuliere derartige Aufgabenstellungen für frei gewählte dreistellige Zahlen (mit unterschiedlichen Ziffern).
Das andere Gruppenmitglied soll deine Aufgabenstellungen lösen.

Aufgabe für Fortgeschrittene:

Auch ohne Computer ist nicht schwer, herauszufinden, wie viele dreistellige Zahlen es gibt. Mit Computer ist es auch interessant: http://maxima-online.org/?inc=r-673670430 . Aber, wie viele dreistellige Zahlen mit unterschiedlichen Ziffern gibt es? Die Kombinatorik liefert schnell eine Antwort.
Ich hätte gerne, dass der Computer diese Zahlen aufschreibt.

Der Programmcode dazu:

H:setify(makelist(i,i,1,9));
Z:setify(makelist(i,i,0,9));
E:Z;
zahlenmenge:cartesian_product(H,Z,E);
zahlenliste:listify(zahlenmenge);
verschiedene_ziffern:sublist(zahlenliste,lambda([x],
cardinality(setify(x))=3));
length(verschiedene_ziffern);

Anmerkung: cardinality(M) ist die Mächtigkeit der Menge M. Die Mächtigkeit einer Menge, ist die Anzahl ihrer Elemente. Die Zahl 199 als Liste ist [1,9,9]. Wenn man die Liste zu einer Menge verwandelt, erhält man {1,9}. Da eine Menge eine Zusammenfassung von wohlunterschieden Objekten unserer Anschauung oder unseres Denkens ist, dürfen keine Ziffern mehrfach vorkommen. Die Umwandlung einer Liste x in eine Menge erfolgt mit setify(x).  Die lambda-Funktion berücksichtigt in der Teilliste (sublist) also nur dreistellige Zahlen mit lauter verschiedenen Ziffern.Liste_in_Menge_1

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r-1271358832

Es geht natürlich auch ohne Maxima:

Matthias Praunegger von http://www.d4e.at hat mir dieses Programm (mit einem anderen Algorithmus) geschickt:

matthias

 

Insertion Sort

Einleitung:
Grundkompetenzen
sind Lesen, Schreiben, Rechnen und Ordnen. Rechnen ist wohl die Grundaufgabe eines Computers. Schreiben hat mich zum Kauf des ersten Computers veranlasst. Lesen kann der Computer auch schon perfekt. Und der Wunsch nach Ordnung hat dazu geführt, dass man beim Programmieren von Anfang an über Sortieralgorithmen nachdenken musste. Ein solcher Algorithmus wird hier behandelt.

Quelle (für Insertion Sort): https://www.youtube.com/watch?v=JPyuH4qXLZ0

Programmcode:

A:[3,2,5,1,10,8];
for i:2 thru length(A) do
block(
wert:A[i],
j:i,
while j>1 and A[j-1]>wert do
block(
A[j]:A[j-1],
j:j-1,
A[j]:wert
)
);
A;

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r-1715728250

Zum Nachlesen: http://de.wikipedia.org/wiki/Insertionsort

 

Schraffierte Fläche berechnen

Schraffierte Fläche berechnen

Man kann hier die 4 Punkte A,B,C und D leicht ablesen. Daraus lässt sich die schraffierte Fläche berechnen. Man kann auch mit dem Geogebra-Zeichenblatt rechnen 🙂

Die Lösung mit dem Zeichenblatt:

flächenintegral

Die Lösung mit dem Zeichenblatt ist weitgehend eine BLACK BOX Methode, daher gibt es noch den Bedarf der rechnerischen Kontrolle!

Programmcode:

g:y=a*x^3+b*x^2+c*x+d;
g1:g,x=-3,y=0;
g2:g,x=0,y=3;
g3:g,x=2,y=0;
g4:g,x=5,y=0;
l:solve([g1,g2,g3,g4],[a,b,c,d]);
kurve:ev(g,l);
f(x):=''rhs(kurve);
F:integrate(f(x),x,-3,2)+abs(integrate(f(x),x,2,5));
F:floor(F*100+0.5)/100.0;

Maxima Onlinehttp://maxima-online.org/?inc=r89496227

Wie die Rechnung funktioniert:

nummeriertes_programm

  1. Wir machen eine Gleichung g mit dem allgemeinen Ansatz für eine Polynomfunktion dritten Grades. Die Koeffizienten a,b,c und d sind unbekannt. 4 Unbekannte bedeutet, dass wir 4 Gleichungen benötigen. Da die ablesbaren Punkte A,B,C und D auf der gesuchten Kurve liegen sollen, kann man ihre Koordinaten in die Gleichung einsetzen.
  2. Wir setzen die Koordinaten des Punktes A in die Gleichung ein.
  3. Wir setzen die Koordinaten des Punktes B in die Gleichung ein.
  4. Wir setzen die Koordinaten des Punktes C in die Gleichung ein.
  5. Wir setzen die Koordinaten des Punktes D in die Gleichung ein.
  6. Wir lösen das System der vier Gleichungen g1,g2,g3 und g4 nach den Unbekannten a,b,c und d auf.
  7. Wir setzen die Lösungen für a,b,c und d in den allgemeinen Ansatz ein und erhalten die Gleichung der Polynomfunktion.
  8. Wir erzeugen die kubische Funktion.
  9. Wir integrieren die kubische Funktion in zwei Teilen. Beim zweiten Teil müssen wir den Absolutbetrag nehmen, weil das bestimmte Integral in diesem Bereich negativ ist und sonst die Fläche kleiner würde.
  10. Wir runden die Fläche auf 2 Nachkommastellen.

Eine Kurvendiskussionsaufgabe mit Lösungen generieren

Aufgabe: Durch Veränderung der Eingabe kann man verschiedene Kurvendiskussionsaufgaben (mit den zu erwartenden Lösungen) generieren.

Maxima Online Programm dafür: http://maxima-online.org/?inc=r687730420

Die generierte Aufgabe soll mit Geogebra gelöst werden!

Hier die kontrollierte Grundaufgabe: http://www.geogebratube.org/student/m113304

Eine erste Übung dazu:

uebung

Und hier wird eine weitere Übungsaufgabe generiert:
http://maxima-online.org/?inc=r-611083516

Berechnung des Gesamtwiderstandes

Berechnung des Gesamtwiderstandes

Man berechne den Gesamtwiderstand der gezeichneten Schaltung!

Programmcode:

""/* SERIENSCHALTUNG */;
"~~"([x]):=xthru(apply("+",x));
nary("~~",110);
""/* PARALLELSCHALTUNG */;
"||"([x]):=xthru(1/apply("+",1/x));
nary("||",110);
""/* GEMISCHTE AUFGABEN */;
Widerstand:[R1=100,R2=30,R3=50,R4=200,R5=50];
Schaltung:(R1||R2)~~R3~~(R4||R5);
Schaltung,Widerstand,numer;

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r799792767

 

 

Allgemeines Dreieck

Allgemeines Dreieck

Aus den ablesbaren Eckpunkten sollen alle anderen Größen berechnet werden!
Ein wichtiger Hinweis: bei Eckpunkten mit ganzzahligen Koordinaten kann man die Fläche leicht durch Kopfrechnen ermitteln.

1. Aufgabe:

a) Man zeichne die Lösung mit dem Geogebra-Zeichenblatt http://www.geogebratube.org/student/m96676
b) Man kontrolliere die Lösungen mit CAS-Maxima.

2. Aufgabe als Zweiergruppenarbeit: Mit dem Zeichenblatt zwei weitere Aufgaben erstellen und bearbeiten.

 

 

Ein Polynom fünften Grades

Ein Polynom fünften Grades

Aufgabe:

Man mache eine (klassische) Kurvendiskussion!

y=-x^5/1800-7*x^4/1800+47*x^3/360-629*x^2/1800-77*x/60+3 ist die gegebene Funktion.

Die schnelle Lösung auf Geogebratube: http://www.geogebratube.org/student/m105761

Überblick über 5 Nullstellen inkl. Grafik:

f:y=-x^5/1800-7*x^4/1800+47*x^3/360-629*x^2/1800-77*x/60+3;
factor(rhs(f));
plot2d(rhs(f),[x,-21,10]);

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r-1032001985

Berechnung der Nullstellen (3 Varianten):

f:y=-x^5/1800-7*x^4/1800+47*x^3/360-629*x^2/1800-77*x/60+3;
realroots(rhs(f));
allroots(rhs(f));
solve(rhs(f)=0,x);

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r1652438503

Berechnung der Extremwerte:

f:y=-x^5/1800-7*x^4/1800+47*x^3/360-629*x^2/1800-77*x/60+3;
ab:diff(rhs(f),x);
realroots(ab),numer;

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r-753313765

Berechnung der Wendepunkte:

f:y=-x^5/1800-7*x^4/1800+47*x^3/360-629*x^2/1800-77*x/60+3;
ab2:diff(rhs(f),x,2);
realroots(ab2),numer;

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r1474707231