Einfache Wahrscheinlichkeitsrechnung

Aufgaben:

  1. Messergebnis:[0,0,2,2,5,4,6,0,9,10,6,5,11,6,6,15,14,1,0,17].
    a) Bestimme die Häufigkeiten.
    b) Bestimme W(x>2).
    c) Wie hoch ist der Erwartungswert?
  2. Messergebnis:[1,2,1,0,5,1,5,6,9,7,1,6,12,14,15,3,7,10,8,12,8,9,8,19,24].
    a) Bestimme die Häufigkeiten.
    b) Bestimme W(x>3).
    c) Wie hoch ist der Erwartungswert?
  3. Messergebnis:[0,0,2,2,5,4,6,0,9,2,3,4,10,8,11,0,6,5,11,6,6,15,14,1,0,17].
    a) Bestimme die Häufigkeiten.
    b) Bestimme W(x>1).
    c) Wie hoch ist der Erwartungswert?

Strichliste – Sortieren hilft:

tipp1a

Strichliste zu 1a:
strichliste_1

Vollständige Lösung Tabellenkalkulation:
Tabellenkalkulation lässt sich gut anwenden, hat aber einen kleinen Nachteil: die Anzahl der Messergebnisse erfordert jeweils Anpassungen. Die Ausgabe ist sehr schön, die mathematische Vorgangsweise aber eher weniger transparent.

strichliste_2

Programmcode:

load(descriptive);
x:[0,0,2,2,5,4,6,0,9,10,6,5,11,6,6,15,14,1,0,17];
k:2;
G:discrete_freq(x);
X:G[1];
H:G[2];
n:length(H);
N:sum(H[i],i,1,n);
p:H/N;
W:sum(p[i],i,k+1,n);
E:sum(p[i]*X[i],i,1,n),numer;
E:floor(E*10+0.5)/10.0;

Das Unterprogramm descriptive ermöglicht Gruppierung mit discrete_freq()

Programmcode mit benutzerdefinierter Funktion:

A:[[0,0,2,2,5,4,6,0,9,10,6,5,11,6,6,15,14,1,0,17],2]
/* EINGABE kann verändert werden */;
f(x,k):=block(
load(descriptive),
G:discrete_freq(x),
X:G[1],
H:G[2],
n:length(H),
N:sum(H[i],i,1,n),
p:H/N,
W:sum(p[i],i,k+1,n),
E:sum(p[i]*X[i],i,1,n),numer,
E:floor(E*10+0.5)/10.0,
"Ergebnis"
);
f(A[1],A[2]);
display(W,E);

Ausführung mit Maxima Onlinehttp://maxima-online.org/?inc=r-1301181831

Programmcode (alle Aufgaben auf einmal):

f(L):=block(
load(descriptive),
Ergebnis:[],
G:discrete_freq(L[1]),
X:G[1],
H:G[2],
n:length(H),
N:sum(H[i],i,1,n),
p:H/N,
W:sum(p[i],i,L[2]+1,n),
E:sum(p[i]*X[i],i,1,n),numer,
E:floor(E*10+0.5)/10.0,
Ergebnis:append(Ergebnis,[W,E])
);
Aufgaben: matrix(
[[0,0,2,2,5,4,6,0,9,10,6,5,11,6,6,15,14,1,0,17],2],
[[1,2,1,0,5,1,5,6,9,7,1,6,12,14,15,3,7,10,8,12,8,9,8,19,24],3],
[[0,0,2,2,5,4,6,0,9,2,3,4,10,8,11,0,6,5,11,6,6,15,14,1,0,17],1]
)
/* Eingabe darf geändert werden */;
A:args(Aufgaben);
map(f,A);

Es gibt also 3 wesentliche Schritte:

pap

Die Ausführung mit Maxima Online: http://maxima-online.org/?inc=r-607858086

Hinweis: ohne Computerunterstützung ist die Anwendung der Gegenwahrscheinlichkeit anzuraten.

Wahrscheinlichkeitsverteilung

Eine Schularbeitsstatistik nach dem österreichischen Notensystem:

Wahrscheinlichkeitsverteilung

Fragen zum “Aufwärmen”:

  1. Wie viele Schüler/innen haben mitgemacht?
  2. Wie viele Schüler/innen haben die Note 2 = “Gut” bekommen?
  3. Wie viele Schüler/innen haben die Note 5 = “Nicht genügend”
    bekommen?
  4. Wie viele Schüler/innen haben eine positive Note bekommen?

Programmcode für die Bestimmung der Wahrscheinlichkeitsverteilung:

X:[1,2,3,4,5];
H:[2,6,3,4,5];
n:length(X);
N:sum(H[i],i,1,n);
P:H/N;
Kontrolle:sum(P[i],i,1,n);

Fragen zur Wahrscheinlichkeitsverteilung der Schularbeitsnoten:

1. Wie groß ist die Wahrscheinlichkeit, dass die Note besser 
   als 3 ist?
2. Wie groß ist die Wahrscheinlichkeit, dass die Note schlechter 
   als 2 ist?
3. Wie groß ist die Wahrscheinlichkeit, dass die Note 
   bestenfalls 2 ist?
4. Wie groß ist die Wahrscheinlichkeit für eine positive Note?

Berechnungen mit Maxima Online: http://maxima-online.org/?inc=r1532874979
mit Fragen: http://maxima-online.org/?inc=r-120341521

Endwert einer nachschüssigen Rente

Endwert einer nachschüssigen Rente

Die Grundaufgabe der Rentenrechnung

Programmcode:

R:5000;
p:4;
n:5;
i:p/100.0;
r:1+i;
E:R*(r**n-1)/i,numer;
E:E*r**2;
E:floor(E*100+0.5)/100.0;

Maxima Online: http://maxima-online.org/?inc=r-337318279

Wie könnte die Aufgabenstellung für die folgende Rechnung formuliert sein?
http://maxima-online.org/?inc=r-1823711827

Binomialverteilung und Approximation durch Normalverteilung

Aufgabe:

Eine faire Münze wird 80 mal geworfen. Wie groß ist die Wahrscheinlichkeit
a) höchstens 45 mal
b) zwischen 36 und 42 mal „Kopf“ zu werfen?

Programmcode:

""/* BINOMIALVERTEILUNG */;
n:80;p:1/2;
W(k):=binomial(n,k)*p**k*(1-p)**(n-k);
WA:sum(W(k),k,0,45),numer;WA:floor(WA*10000+0.5)/10000.0;
WB:sum(W(k),k,36,42),numer;WB:floor(WB*10000+0.5)/10000.0;
""/* NORMALVERTEILUNG */;
m:n*p;s:sqrt(n*p*(1-p));
load(distrib)$
WA:cdf_normal(45,m,s),numer;WA:floor(WA*10000+0.5)/10000.0;
WB:cdf_normal(42,m,s)-cdf_normal(36,m,s),numer;
WB:floor(WB*10000+0.5)/10000.0;

Maxima Online:
http://maxima-online.org/?inc=r-1791114831
auch Binomialverteilung mit Unterprogramm:
http://maxima-online.org/?inc=r680017970

Übungen (mit Binomialverteilung):

1. Wie groß ist die Wahrscheinlichkeit
a) mindestens 30 mal Kopf,
b) 30 bis 50 mal Kopf,
c) höchstens 50 mal Kopf zu werfen?
2. Wie (1) aber mit insgesamt 90 Würfen.

Für die folgenden Aufgaben verwenden wir das GeogebraBook. Zwischenresultate können auch auf Papier notiert werden.

3. Man zeichne die Binomialverteilung für n=80 und p=1/2 mit 
   Blatt(1,1).
4. Man berechne W(x<45) für n=80 und p=1/2 mit Blatt(1,1).
5. Man berechne W(35<x<50) für n=80 und p=1/2 mit Blatt(1,1).

 


GeogebraBook zum Thema: http://geogebratube.org/student/b119421#


Lineare Regression

Learning App: http://LearningApps.org/view361083

Man kontrolliere die einzelnen Rechnungen mit dem Geogebrazeichenblatt: http://www.geogebratube.org/student/m96676

Maxima-Online: http://maxima-online.org/?inc=r-2113822514


Geogebrabook zum Thema: http://geogebratube.org/student/b119441#


Eine Polynomfunktion zu einer gegebenen Punkteliste bestimmen

Aufgabe:

Zu einer gegebenen (und geeigneten) Liste von Punkte ist die passende Polynomfunktion zu bestimmen. Der Grad des Polynoms ist automatisch um eins kleiner als die Anzahl der Punkte!

Programmcode:

kill(all);
Punkt:[[-3,0],[0,3],[2,0],[5,0]];
n:length(Punkt);
Grad:n-1;
g(x):=x[2]=sum(a[i]*x[1]^(n-i),i,1,Grad)+a[n];
Gleichungen:map(g,Punkt);
Unbekannte:makelist(a[i],i,1,n);
l:solve(Gleichungen,Unbekannte);
y=Unbekannte.makelist(x^(n-i),i,1,n),l;

Maxima Online: http://maxima-online.org/?inc=r-1848088314

Erklärung der Berechnung: prog-punkte

  1. Löschen aller Speicher (nicht notwendig!).
  2. Liste der gegebenen Punkte –> EINGABE (darf verändert werden).
  3. Anzahl der gegebenen Punkte.
  4. Der Grad des gesuchten Polynoms ist um eins kleiner als die Anzahl der gegebenen Punkte.
  5. Funktionsmuster für die Bestimmungsgleichung der Polynomfunktion.
  6. Das Funktionsmuster auf die Punkteliste anwenden. Die Koordinaten der Punkte werden eingesetzt und die Liste der Gleichungen automatisch erzeugt.
  7. Die Liste der Unbekannten erzeugen. Die Verwendung von indizierten Koeffizienten ist notwendig.
  8. Lösung des Gleichungssystems.
  9. Die gesuchte Funktion mit Skalarmultiplikation (von Vektoren = Listen) erzeugen.

Noch eine Aufgabe inkl. Graph und Faktorenzerlegung:
http://maxima-online.org/?inc=r-1201857931

Berechnung des Endkapitals bei unregelmäßigen Zahlungen

Grundaufgabe:

Quelle: http://www.lungau-academy.at/Mathematik-Tests/Fuenf_aufeinanderfolgende_Zahlungen.htm (bisher nur für Windows getestet).

„“/*
Jemand zahlt sofort 7665 €,
nach einem Jahr 4840 €,
nach zwei Jahren 3526 €,
nach drei Jahren 339 € und
nach vier Jahren 3820 €.
Bei einem Zinssatz von 5.125 %
ergibt sich nach 11 Jahren
das Endkapital Kn €.*/;

Programmcode:

Zahlung:[[7665,0],[4840,1],[3526,2],[339,3],[3820,4]];
p:5.125;
r:1+p/100.0;
n:11;
BW(x):=x[1]/r^x[2];
Barwert:map(BW,Zahlung);
m:length(Barwert);
Ko:sum(Barwert[i],i,1,m);
Kn:Ko*r^n;
Kn:floor(Kn*100+0.5)/100.0;

Lösung mit Maxima Onlinehttp://maxima-online.org/?inc=r-886888242

Aufgaben:
(Ausgangssituation ist immer die Grundaufgabe)

  1. Wie hoch ist der Endwert, wenn der Zinssatz auf 3% verringert wird?
  2. Wie hoch ist der Endwert, wenn die zweite Zahlung um € 2000,– höher ist und der Zinssatz nur 1,5% beträgt?
  3. Wie ist es, wenn die fünfte Zahlung erst nach 7 Jahren erfolgt?

Erklärung des Programms:

code

  1. Liste mit Zahlungen und Fälligkeit (in jahren nach Beginn) -> EINGABE
  2. Zinssatz in % dek. p.a. –> EINGABE
  3. Berechnung de Aufzinsungsfaktors
  4. Laufzeit in Jahren –> EINGABE
  5. Barwertfunktion mit Liste als Argument
  6. Anwendung der Barwertfunktion auf die Zahlungsliste
  7. Länge der Barwertliste
  8. Summe aller Barwerte („Anfangskapital“)
  9. Endwert (Endkapital)
  10. Runden des Endkapitals auf zwei Nachkommastellen

 

Flächen und Listenverarbeitung

Flächen und Listenverarbeitung

Das Fünfeck, welches hier in sechs rechtwinkelige Dreiecke zerlegt wurde, hat eine Fläche von 52 cm² (was man durch Kopfrechnen herausfinden kann). Welch komplexer Vorgang diese Kopfrechnung ist, kann man durch Formalisierung mit Listenverarbeitung herausfinden.

Dabei kann man viel Verständnis für ein Koordinatensystem erreichen.

Notwendige Listen sind:

  1. die Liste der Punkte
  2. die Liste der rechtwinkeligen Dreiecke
  3. die Liste der Kathetenpaare

1. Aufgabe:

Man bestimme die notwendigen Listen durch Ablesen aus der Zeichnung.

Programmcode (Formalisierung):

  1. Liste der Punkte
    A:[1,5];B:[5,1];C:[10,1];D:[13,5];E:[7,8];F:[7,5];G:[5,5];H:[10,5];
    Punkt:[A,B,C,D,E,F,G,H];
  2. Liste der rechtwinkeligen Dreiecke
    D1:[A,B,G];D2:[C,G,B];D3:[G,C,H];D4:[C,D,H];D5:[E,A,F];D6:[D,E,F];
    Dreieck:[D1,D2,D3,D4,D5,D6];
  3. Liste der Kathetenpaare
    Nicht ablesen, sondern berechnen!

2. Aufgabe:

Zeichne die Dreiecksliste mit Geogebra:

[[[1, 5], [5, 1], [5, 5]], [[10, 1], [5, 5], [5, 1]], 
[[5, 5], [10, 1], [10, 5]], [[10, 1], [13, 5], [10, 5]], 
[[7, 8], [1, 5], [7, 5]], [[13, 5], [7, 8], [7, 5]]]

So geht es laut Youtubehttp://youtu.be/721h4vkwfNU

3. Aufgabe:

Flächenberechnungen:

Man könnte leicht aus der Dreiecksliste die einzelnen Flächen nach der Heronschen Formel ermitteln. Aber das eignet sich ja nicht zum Kopfrechnen, und genau das wollten wir ja analysieren. Also stellt sich die Frage: Ablesen der Kathetenlängen? Das wäre wohl „unsportlich“.

Wir berechnen zunächst die drei Seiten der Dreiecke in der Dreiecksliste. Wir arbeiten das an einem Dreieck aus und verwenden danach Listenarithmetik.

Das ausgewählte Dreieck sei D1.

D1:[[1, 5], [5, 1], [5, 5]];

Programmcode für die Berechnung der Strecken mit Listenverarbeitung:

D1:[[1, 5], [5, 1], [5, 5]];
S1:setify(D1);
P1:powerset(S1,2);
P1:listify(P1);
S1:map(listify,P1);

Maxima liefert:

Seiten:[[[1, 5], [5, 1]], [[1, 5], [5, 5]], [[5, 1], [5, 5]]]

Daraus können wir nunmehr die Seitenlängen berechnen!

Eine Seitenlänge:

Herkömmlich: http://maxima-online.org/?inc=r-968527119

Mit komplexen Zahlen: http://maxima-online.org/?inc=r1711871624

Alle drei Seitenlängen und die Fläche für ein Dreieck:http://maxima-online.org/?inc=r1264415508

Für die Abrechnung der gesamten Dreiecksliste verwenden wir die gute alte FOR-Schleife:
http://maxima-online.org/?inc=r41436217

Programmcode:

D:[[[1, 5], [5, 1], [5, 5]], [[10, 1], [5, 5], [5, 1]], 
[[5, 5], [10, 1], [10, 5]], [[10, 1], [13, 5], [10, 5]], 
[[7, 8], [1, 5], [7, 5]], [[13, 5], [7, 8], [7, 5]]];
n:length(D);
s(X):=sqrt(X[1]^2+X[2]^2);
Gesamt:0;
for i:1 thru n do block(D1:D[i],
S1:setify(D1),
P1:powerset(S1,2),
P1:listify(P1),
S1:map(listify,P1),
AS:makelist(S1[i][2]-S1[i][1],i,1,3),
Seiten:map(s,AS),
Seite:sort(Seiten),
Kathetenpaar:[Seite[1],Seite[2]],
Flaeche:Seite[1]*Seite[2]/2,
Gesamt:Gesamt+Flaeche,
display(Kathetenpaar,Flaeche));
display(Gesamt);

Regressionsrechnung (partielle Ableitungen)

Altes Material als Ausgang (eventuell mit der rechten Maustaste herunterladen)

D1870_F_vollstaendige_Loesung_lineare_Regression.wxmx
D1871_F_vollstaendige_Loesung_quadratische_Regression.wxmx
D1872_F_vollstaendige_Loesung_kubische_Regression.wxmx

Wir werden das mit Maxima Online bearbeiten.

Programmcode Lineare Regression:

kill(all);
x:[1,2,3,4,5];y:[11,21,31,41,51];n:length(x);
f(a,b):=sum((y[i]-a*x[i]-b)**2,i,1,n);
ab1:diff(f(a,b),a);
ab2:diff(f(a,b),b);
g1:ab1=0;
g2:ab2=0;
g1:g1,expand;
g2:g2,expand;
l:solve([g1,g2],[a,b]);
Regressionsgerade:Y=a*X+b,l;

Verarbeitung Lineare Regression: http://maxima-online.org/?inc=r-1428388758

Programmcode Quadratische Regression:

kill(all);
x:[1,2,3,4,5];y:[6,11,18,27,38];n:length(x);
f(a,b,c):=sum((y[i]-a*x[i]**2-b*x[i]-c)**2,i,1,n);
ab1:diff(f(a,b,c),a),expand;
ab2:diff(f(a,b,c),b),expand;
ab3:diff(f(a,b,c),c),expand;
g1:ab1=0;
g2:ab2=0;
g3:ab3=0;
l:solve([g1,g2,g3],[a,b,c]);
Regressionsparabel:Y=a*X**2+b*X+c,l;

Verarbeitung Quadratische Regression: http://maxima-online.org/?inc=r1771287512

Programmcode Kubische Regression:

kill(all);
x:[1,2,3,4,5];y:[11,18,37,74,135];n:length(x);
f(a,b,c,d):=sum((y[i]-a*x[i]**3-b*x[i]**2-c*x[i]-d)**2,i,1,n);
ab1:diff(f(a,b,c,d),a),expand;
ab2:diff(f(a,b,c,d),b),expand;
ab3:diff(f(a,b,c,d),c),expand;
ab4:diff(f(a,b,c,d),d),expand;
g1:ab1=0;
g2:ab2=0;
g3:ab3=0;
g4:ab4=0;
l:solve([g1,g2,g3,g4],[a,b,c,d]);
Regressions_kubische_Parabel:Y=a*X**3+b*X**2+c*X+d,l;

Verarbeitung Kubische Regression: http://maxima-online.org/?inc=r-1601989999