Flächenintegral

Aufgabe:
Man kontrolliere die Flächenberechnung laut Geogebra. Die Funktion darf als gegeben angenommen werden.

loesmi

Programmcode:

ratprint:false;

f(x):=0.1*x^3-0.4*x^2-1.1*x+3;
F(x):=integrate(f(x),x);
F(x);

F1:integrate(f(x),x,-3,2),numer;
F2:integrate(f(x),x,2,5),numer;
F:F1-F2,numer;

r(x):=floor(x*100+0.5)/100.0;
map(r,[F1,F2,F]);

Maxima Online: http://maxima-online.org/?inc=r386760919

Ergebnis mit Maxima:

Teilfläche_1 Teilfläche_2 Gesamtfläche
11,46 FE 2,92 FE 14,38 FE

 

Vollkommene Zahlen

Hier bin ich auf vollkommene Zahlen gestoßen: http://youtu.be/bk_Kjpl2AaA

Hier habe ich nachgelesen: http://de.wikipedia.org/wiki/Vollkommene_Zahl

Dieses Programm werden wir brauchen:

for a:1 thru 10000 do block(
T[a]:[],
for i:1 thru a do if mod(a,i)=0 then T[a]:append(T[a],[i]),
n:length(T[a]),
if sum(T[a][i],i,1,n-1)=T[a][n] then disp(a,"ist eine 
vollkommene Zahl","")
);

Maxima Onlinehttp://maxima-online.org/?inc=r-341553497

Mit verbesserter Ausgabehttp://maxima-online.org/?inc=r-820343253

Kubische Polynomfunktion

Grundaufgabe:
maxdo

Lösungsweg:
Es sind vier Punkte gegeben. Dass es sich um offenbar um Extremwerte und Nullstellen handelt, spielt vorläufig keine Rolle.
In Geogebra http://www.geogebratube.org/student/m96676 kann man Punkte mit nicht ganzzahligen Koordinaten nicht direkt eingeben. Man muss die Eingabezeile verwenden.

  • Format der Eingabe: Punkt = (x,y)
  • Wenn alle Punkte eingegeben sind erzeugen wird die Kubische Parabel mit polynom({A,B,C,D}) und notieren diese.

ergebnisgeogebra

Man kann die Funktion auch mit Maxima Online gemäß https://casmaxima.wordpress.com/2014/04/08/ein-polynom-zur-einer-gegebenen-punkteliste-bestimmen/ bestimmen! Einfach die Punkte in die Punkteliste eintragen!

Einfache Wahrscheinlichkeitsrechnung

Aufgaben:

  1. Messergebnis:[0,0,2,2,5,4,6,0,9,10,6,5,11,6,6,15,14,1,0,17].
    a) Bestimme die Häufigkeiten.
    b) Bestimme W(x>2).
    c) Wie hoch ist der Erwartungswert?
  2. Messergebnis:[1,2,1,0,5,1,5,6,9,7,1,6,12,14,15,3,7,10,8,12,8,9,8,19,24].
    a) Bestimme die Häufigkeiten.
    b) Bestimme W(x>3).
    c) Wie hoch ist der Erwartungswert?
  3. Messergebnis:[0,0,2,2,5,4,6,0,9,2,3,4,10,8,11,0,6,5,11,6,6,15,14,1,0,17].
    a) Bestimme die Häufigkeiten.
    b) Bestimme W(x>1).
    c) Wie hoch ist der Erwartungswert?

Strichliste – Sortieren hilft:

tipp1a

Strichliste zu 1a:
strichliste_1

Vollständige Lösung Tabellenkalkulation:
Tabellenkalkulation lässt sich gut anwenden, hat aber einen kleinen Nachteil: die Anzahl der Messergebnisse erfordert jeweils Anpassungen. Die Ausgabe ist sehr schön, die mathematische Vorgangsweise aber eher weniger transparent.

strichliste_2

Programmcode:

load(descriptive);
x:[0,0,2,2,5,4,6,0,9,10,6,5,11,6,6,15,14,1,0,17];
k:2;
G:discrete_freq(x);
X:G[1];
H:G[2];
n:length(H);
N:sum(H[i],i,1,n);
p:H/N;
W:sum(p[i],i,k+1,n);
E:sum(p[i]*X[i],i,1,n),numer;
E:floor(E*10+0.5)/10.0;

Das Unterprogramm descriptive ermöglicht Gruppierung mit discrete_freq()

Programmcode mit benutzerdefinierter Funktion:

A:[[0,0,2,2,5,4,6,0,9,10,6,5,11,6,6,15,14,1,0,17],2]
/* EINGABE kann verändert werden */;
f(x,k):=block(
load(descriptive),
G:discrete_freq(x),
X:G[1],
H:G[2],
n:length(H),
N:sum(H[i],i,1,n),
p:H/N,
W:sum(p[i],i,k+1,n),
E:sum(p[i]*X[i],i,1,n),numer,
E:floor(E*10+0.5)/10.0,
"Ergebnis"
);
f(A[1],A[2]);
display(W,E);

Ausführung mit Maxima Onlinehttp://maxima-online.org/?inc=r-1301181831

Programmcode (alle Aufgaben auf einmal):

f(L):=block(
load(descriptive),
Ergebnis:[],
G:discrete_freq(L[1]),
X:G[1],
H:G[2],
n:length(H),
N:sum(H[i],i,1,n),
p:H/N,
W:sum(p[i],i,L[2]+1,n),
E:sum(p[i]*X[i],i,1,n),numer,
E:floor(E*10+0.5)/10.0,
Ergebnis:append(Ergebnis,[W,E])
);
Aufgaben: matrix(
[[0,0,2,2,5,4,6,0,9,10,6,5,11,6,6,15,14,1,0,17],2],
[[1,2,1,0,5,1,5,6,9,7,1,6,12,14,15,3,7,10,8,12,8,9,8,19,24],3],
[[0,0,2,2,5,4,6,0,9,2,3,4,10,8,11,0,6,5,11,6,6,15,14,1,0,17],1]
)
/* Eingabe darf geändert werden */;
A:args(Aufgaben);
map(f,A);

Es gibt also 3 wesentliche Schritte:

pap

Die Ausführung mit Maxima Online: http://maxima-online.org/?inc=r-607858086

Hinweis: ohne Computerunterstützung ist die Anwendung der Gegenwahrscheinlichkeit anzuraten.

Extremwerte

Aufgabe: Das Maximum in der folgenden Grafik muss rechnerisch nachgeprüft werden.

Kubische_Parabel

 

Rechnerische Kontrolle mit Maxima-Online:
http://maxima-online.org/?inc=r819714133

Übung: Man kontrolliere die Extremwerte durch Berechnung mit CAS Maxima http://maxima.online.org
Man kann sich auch mit dem Geogebra-Zeichenblatt einen Überblick verschaffen: http://www.geogebratube.org/student/m96676

MAXI_MO
Programmcode dazu:

Punkt: matrix(
[-3,0],
[0,-1],
[3,2],
[6,0]
);
Punkt:args(Punkt);
f(x):=x[2]=a*x[1]^3+b*x[1]^2+c*x[1]+d;
g:map(f,Punkt);
l:solve(g,[a,b,c,d]);
KP:y=a*x^3+b*x^2+c*x+d,l;

ratprint:false;
e:solve(diff(rhs(KP),x)=0,x),numer;
x1:x,e[1];x2:x,e[2];
y1:rhs(KP),x=x1;y2:rhs(KP),x=x2;
x1:floor(x1*100+0.5)/100.0;x2:floor(x2*100+0.5)/100.0;
y1:floor(y1*100+0.5)/100.0;y2:floor(y2*100+0.5)/100.0;
Extremwerte:[[x1,y1],[x2,y2]];

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r2087016275

Sein oder nicht Sein

Aufgabe:
Tautologien sind immer wahr!

Man zeige: „Be or not to be“ ist eine Tautologie!
http://de.wikipedia.org/wiki/Sein_oder_Nichtsein,_das_ist_hier_die_Frage

Programmcode:
Version 1

n(u):=1-u;
o(x,y):=x+y-x*y;
bnb(x,y):=o(x,n(x));
bnb(1,1);
bnb(1,0);
bnb(0,1);
bnb(0,0);

Version 2

n(u):=1-u;
o(u,v):=u+v-u*v;
bnb(x):=o(x[1],n(x[1]));
W:{1,0};
WT:reverse(listify(cartesian_product(W,W)));
Result:map(bnb,WT);
[transpose(WT),transpose(Result)];

Version 3

n(u):=not u;
o(u,v):=u or v;
bnb(x):=o(x[1],n(x[1]));
W:{true,false};
WT:reverse(listify(cartesian_product(W,W)));
Result:map(bnb,WT);
[transpose(WT),transpose(Result)];

Maxima-Online: http://maxima-online.org/?inc=r-202349713

Verbesserter Algorithmus: http://maxima-online.org/?inc=r-1341626167

Mit Boolescher Algebra: http://maxima-online.org/?inc=r-197911884

Implikation und Äquivalenz

Hintergrund:

Die Aussagenlogik ist ein Teilgebiet der Logik, das sich mit Aussagen und deren Verknüpfung befasst, ausgehend von Elementaraussagen, denen ein Wahrheitswert (wahr oder falsch)  zugeordnet wird. Der Wahrheitswert einer zusammengesetzten Aussage lässt sich ohne zusätzliche Informationen aus den Wahrheitswerten ihrer Teilaussagen bestimmen.

Man berechne die Implikation mit Listenverarbeitung
(Abbildung aus einem Skriptum des Jahres 2003)

Implikation

Programmcode:

imp(a,b):= not a or b;
A:{true,false};
W:listify(cartesian_product(A,A));
f(x):=imp(x[1],x[2]);
ERG:map(f,W);
WT:[transpose(W),transpose(ERG)];

Erläuterungen dazu:

1. imp(a,b) ist eine benutzerdefinierte Funktion in zwei Variablen
2. eine Aussage kann wahr oder falsch sein
3. cartestian_product(A,B) ist die Produktmenge AxA, listify macht
   aus der Menge eine Liste
4. Funktion mit einem geordneten Paar als Argument
5. map erzeugt das elementweise Ergebnis der Implikation
6. mit transpose entsteht eine spaltenweise Darstellung

Maxima-Online: http://maxima-online.org/?inc=r2019918161

Aufgabe: Man ändere bzw. ergänze die Implikation auf Äquivalenz eqv(a,b):=imp(a,b) and imp(b,a);

Programmcode:

imp(a,b):= not a or b;
eqv(a,b):=imp(a,b) and imp(b,a);
A:{true,false};
W:listify(cartesian_product(A,A));
f(x):=imp(x[1],x[2]);
g(x):=eqv(x[1],x[2]);
ERG1:map(f,W);
ERG2:map(g,W);
WT:[transpose(W),transpose(ERG1)];
WT:[transpose(W),transpose(ERG2)];

Maxima-Online: http://maxima-online.org/?inc=r234229047

Vermischte Aufgaben

Maxima-Online-Beispiele

Thema
Link
Betriebsoptimum und langfristige Preisunterrgrenze
Maximaler Umsatz (Maturaball Tombola)
Kleiner-Relation
Volumen eines Drehkegels
Der natürliche Logarithmus kann als Ausnahmefalls bei der Integration von xn angesehen werden!
Berechnung des Endkapitals (Zinseszinsrechnung)
Steigung der Sekante (Differenzenquotient)
Auf Primzahlen prüfen (W. Haager)
Lineare Optimierung (Grundaufgabe)
Wahrheits(werte)tafel der Implikation
Überbestimmtes Gleichungssystem (Pseudoinverse)


Wahrscheinlichkeitsverteilung

Bild

Eine Schularbeitsstatistik nach dem österreichischen Notensystem:

Wahrscheinlichkeitsverteilung

Fragen zum “Aufwärmen”:

  1. Wie viele Schüler/innen haben mitgemacht?
  2. Wie viele Schüler/innen haben die Note 2 = “Gut” bekommen?
  3. Wie viele Schüler/innen haben die Note 5 = “Nicht genügend”
    bekommen?
  4. Wie viele Schüler/innen haben eine positive Note bekommen?

Programmcode für die Bestimmung der Wahrscheinlichkeitsverteilung:

X:[1,2,3,4,5];
H:[2,6,3,4,5];
n:length(X);
N:sum(H[i],i,1,n);
P:H/N;
Kontrolle:sum(P[i],i,1,n);

Fragen zur Wahrscheinlichkeitsverteilung der Schularbeitsnoten:

1. Wie groß ist die Wahrscheinlichkeit, dass die Note besser 
   als 3 ist?
2. Wie groß ist die Wahrscheinlichkeit, dass die Note schlechter 
   als 2 ist?
3. Wie groß ist die Wahrscheinlichkeit, dass die Note 
   bestenfalls 2 ist?
4. Wie groß ist die Wahrscheinlichkeit für eine positive Note?

Berechnungen mit Maxima Online: http://maxima-online.org/?inc=r1532874979
mit Fragen: http://maxima-online.org/?inc=r-120341521