Kurvendiskussion

Aufgabe aus Geogebra-Tube: http://www.geogebratube.org/student/m59471

Gegeben sind also 4 Punkte:

A:[x=2,y=2];
B:[x=4.84,y=-0.4];
C:[x=7.68,y=2.3];
D:[x=11,y=0];

Lösung der Teilaufgabe (a): http://maxima-online.org/?inc=r1540912938

ratprint:false;
A:[x=2,y=2];
B:[x=4.84,y=-0.4];
C:[x=7.68,y=2.3];
D:[x=11,y=0];
g:y=a*x^3+b*x^2+c*x+d;
g1:g,A;
g2:g,B;
g3:g,C;
g4:g,D;
l:solve([g1,g2,g3,g4],[a,b,c,d]),numer;
koeff:[a,b,c,d],l;
koeff:floor(koeff*100+0.5)/100.0;
f:[x^3,x^2,x,1].koeff;

Lösung der Teilaufgabe (b):

Lösung der Teilaufgabe (c):

Lösung der Teilaufgabe (d):

Werbeanzeigen

Steigungsdreieck

Geogebra: http://www.geogebratube.org/student/m3675

Maxima Online: http://maxima-online.org/?inc=r-303609561

Maxima on Android:
Gerade(x,y):=y=k*x+d;
EINGABE:[k=1,d=3];
Gerade:ev(Gerade(x,y),EINGABE);
g1:Gerade,x=x1,y=y1;
g2:Gerade,x=x2,y=y2;
g:g2-g1;
k:g/rhs(g);

Quadratische Funktion

Aufgabe:

aufgabe1

Anleitung zur Lösung:

  1. Man muss die Koordinaten der drei Punkte A, B, C in y=ax²+bx+c einsetzen. Dadurch erhält man drei Gleichungen mit den drei Unbekannten a,b und c. Wenn man das Gleichungssystem löst, erhält man a=1, b=-8 und c=15.
  2. A und B sind die Schnittpunkte mit der x-Achse. Da y=0 ist, nennt man sie Nullstellen. Manchmal gibt man unter dem Begriff Nullstellen nur die x-Werte an, da dort y=0 ist.
  3. Man muss die Gleichung x² -8x+15=0 lösen, nach der Mitternachtsformel („Große Lösungsformel für quadratische Gleichungen“).
  4. C ist ein Extremwert, und zwar ein Minimum.
  5. In einem Minimum gibt es eine horizontale Tangente, daher muss die erste Ableitung NULL sein. Die erste Ableitung ist nämlich die Steigung der Tangente. Wir müssen also die Gleichung 2x-8=0 lösen. Den zugehörigen y-Wert erhält man, indem man in die Funktions-Gleichung einsetzt.

Link zu Maxima Online: http://maxima-online.org/?inc=r221832178
„Klassische Lösung“: http://maxima-online.org/?inc=r-1817214728

Das ist eine Lösung mit viel Listenverarbeitung!
(%i1) Punkt:[[3,0],[4,-1],[5,0]];
(%o1)                     [[3, 0], [4, - 1], [5, 0]]
(%i2) g(x):=x[2]=a*x[1]^2+b*x[1]+c;
                                         2
(%o2)                    g(x) := x  = a x  + b x  + c
                                  2      1      1
(%i3) Gleichungen:map(g,Punkt);
(%o3)    [0 = c + 3 b + 9 a, - 1 = c + 4 b + 16 a, 0 = c + 5 b + 25 a]
(%i4) Unbekannte:[a,b,c];
(%o4)                              [a, b, c]
(%i5) Loesung:solve(Gleichungen,Unbekannte);
(%o5)                     [[a = 1, b = - 8, c = 15]]
(%i6) f(x):=a*x^2+b*x+c;
                                       2
(%o6)                       f(x) := a x  + b x + c
(%i7) ab:diff(f(x),x);
(%o7)                              2 a x + b
(%i8) Parabel:f(x),Loesung;
                                  2
(%o8)                            x  - 8 x + 15
(%i9) Ableitung:ab,Loesung;
(%o9)                               2 x - 8
(%i10) Nullstelle:realroots(Parabel);
(%o10)                          [x = 3, x = 5]
(%i11) y_Werte_NS:Parabel,Nullstelle;
(%o11)                                 0
(%i12) Extremwert:realroots(Ableitung);
(%o12)                              [x = 4]
(%i13) y_Werte_NS:Parabel,Extremwert;
(%o13)                                - 1
(%i14)

Ein pensionierter Mathematiker auf Bergtour

Quelle der Aufgabenstellung: Roolfs: nibis.ni.schule.de/~lbs-gym/jahrgang111pdf/Bergwanderung.pdf vom 18.11.2013

Link zu Maxima Online: http://maxima-online.org/?inc=r1505083676

(%i1) "*"/* Ein Pensionist geht auf einen Berg mit dem 
Querschnittsprofil (W-O) f(x)=0,038x²-0,004x³ */;
(%o1)                                  *
(%i2) "*"/* Maßeinheit ist km */;
(%o2)                                  *
(%i3) f(x):=0.038*x^2-0.004*x^3;
                                         2          3
(%o3)                     f(x) := 0.038 x  - 0.004 x
(%i4) plot2d([f(x)],[x,-1,10]);
(%o4) 
(%i5) plot2d([f(x)],[x,-1,10]);;
"*";
(%o5)                                  *
(%i6) "*"/* a) Welche Querschnittslänge hat der Berg ? */;
(%o6)                                  *
(%i7) N:realroots(f(x)),numer;
(%o7)                          [x = 9.5, x = 0]
(%i8) Querschnittslaenge:N[1];
(%o8)                               x = 9.5
(%i9) "*"/* b) Wie hoch ist der Berg? */;
(%o9)                                  *
(%i10) ab:diff(f(x),x);
                                               2
(%o10)                        0.076 x - 0.012 x
(%i11) E:realroots(ab),numer;
(%o11)                  [x = 6.333333343267441, x = 0]
(%i12) Berghoehe:f(x),E[1];
(%o12)                         0.50807407407407
(%i13) "*"/* c) Wie hoch ist der maximale Anstieg von Westen 
(von Osten)? */;
(%o13)                                 *
(%i14) "*"/* Diese Fragestellung muss man sehr genau untersuchen! */;
(%o14)                                 *
(%i15) ab2:diff(ab,x);
(%o15)                          0.076 - 0.024 x
(%i16) W:realroots(ab2),numer;
(%o16)                      [x = 3.166666656732559]
(%i17) Anstieg_Wendepunkt:ab,W;
(%o17)                         0.12033333333333
(%i18) maximaler_Anstieg:ab,N[1] /* Randextremum */;
(%o18)                              - 0.361
(%i19)

Eine Kurvendiskussionsaufgabe mit Lösungen generieren

Aufgabe: Durch Veränderung der Eingabe kann man verschiedene Kurvendiskussionsaufgaben (mit den zu erwartenden Lösungen) generieren.

Maxima Online Programm dafür: http://maxima-online.org/?inc=r687730420

Die generierte Aufgabe soll mit Geogebra gelöst werden!

Hier die kontrollierte Grundaufgabe: http://www.geogebratube.org/student/m113304

Eine erste Übung dazu:

uebung

Und hier wird eine weitere Übungsaufgabe generiert:
http://maxima-online.org/?inc=r-611083516

Ein Polynom fünften Grades

Ein Polynom fünften Grades

Aufgabe:

Man mache eine (klassische) Kurvendiskussion!

y=-x^5/1800-7*x^4/1800+47*x^3/360-629*x^2/1800-77*x/60+3 ist die gegebene Funktion.

Die schnelle Lösung auf Geogebratube: http://www.geogebratube.org/student/m105761

Überblick über 5 Nullstellen inkl. Grafik:

f:y=-x^5/1800-7*x^4/1800+47*x^3/360-629*x^2/1800-77*x/60+3;
factor(rhs(f));
plot2d(rhs(f),[x,-21,10]);

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r-1032001985

Berechnung der Nullstellen (3 Varianten):

f:y=-x^5/1800-7*x^4/1800+47*x^3/360-629*x^2/1800-77*x/60+3;
realroots(rhs(f));
allroots(rhs(f));
solve(rhs(f)=0,x);

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r1652438503

Berechnung der Extremwerte:

f:y=-x^5/1800-7*x^4/1800+47*x^3/360-629*x^2/1800-77*x/60+3;
ab:diff(rhs(f),x);
realroots(ab),numer;

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r-753313765

Berechnung der Wendepunkte:

f:y=-x^5/1800-7*x^4/1800+47*x^3/360-629*x^2/1800-77*x/60+3;
ab2:diff(rhs(f),x,2);
realroots(ab2),numer;

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r1474707231

Regressionsrechnung (partielle Ableitungen)

Altes Material als Ausgang (eventuell mit der rechten Maustaste herunterladen)

D1870_F_vollstaendige_Loesung_lineare_Regression.wxmx
D1871_F_vollstaendige_Loesung_quadratische_Regression.wxmx
D1872_F_vollstaendige_Loesung_kubische_Regression.wxmx

Wir werden das mit Maxima Online bearbeiten.

Programmcode Lineare Regression:

kill(all);
x:[1,2,3,4,5];y:[11,21,31,41,51];n:length(x);
f(a,b):=sum((y[i]-a*x[i]-b)**2,i,1,n);
ab1:diff(f(a,b),a);
ab2:diff(f(a,b),b);
g1:ab1=0;
g2:ab2=0;
g1:g1,expand;
g2:g2,expand;
l:solve([g1,g2],[a,b]);
Regressionsgerade:Y=a*X+b,l;

Verarbeitung Lineare Regression: http://maxima-online.org/?inc=r-1428388758

Programmcode Quadratische Regression:

kill(all);
x:[1,2,3,4,5];y:[6,11,18,27,38];n:length(x);
f(a,b,c):=sum((y[i]-a*x[i]**2-b*x[i]-c)**2,i,1,n);
ab1:diff(f(a,b,c),a),expand;
ab2:diff(f(a,b,c),b),expand;
ab3:diff(f(a,b,c),c),expand;
g1:ab1=0;
g2:ab2=0;
g3:ab3=0;
l:solve([g1,g2,g3],[a,b,c]);
Regressionsparabel:Y=a*X**2+b*X+c,l;

Verarbeitung Quadratische Regression: http://maxima-online.org/?inc=r1771287512

Programmcode Kubische Regression:

kill(all);
x:[1,2,3,4,5];y:[11,18,37,74,135];n:length(x);
f(a,b,c,d):=sum((y[i]-a*x[i]**3-b*x[i]**2-c*x[i]-d)**2,i,1,n);
ab1:diff(f(a,b,c,d),a),expand;
ab2:diff(f(a,b,c,d),b),expand;
ab3:diff(f(a,b,c,d),c),expand;
ab4:diff(f(a,b,c,d),d),expand;
g1:ab1=0;
g2:ab2=0;
g3:ab3=0;
g4:ab4=0;
l:solve([g1,g2,g3,g4],[a,b,c,d]);
Regressions_kubische_Parabel:Y=a*X**3+b*X**2+c*X+d,l;

Verarbeitung Kubische Regression: http://maxima-online.org/?inc=r-1601989999