Mitternachtsformel

Mitternachtsformel Hier befassen wir uns mit dem Lösen von quadratischen Gleichungen.

Programmcode:
g1:a*x^2+b*x+c=0;
L:solve(g1);
Einsetzen:L,a=1,b=-8,c=15

Maxima Online: http://maxima-online.org/?inc=r2099060948

Werbeanzeigen

Diverse Aufgaben zur Kosten- und Preistheorie

Begriffserklärung:
Die Kosten- und Preistheorie ist eine Anwendung der Analysis (Infinitesimalrechnung) auf Fragestellungen der Betriebswirtschaftslehre. Das Anliegen ist, Erklärungsmodelle zu liefern.

Themen:

  • Nachfragefunktion
  • Sättigungsmenge
  • Preisobergrenze
  • Umsatz (Erlös)
  • Kosten
  • Gewinn

Aufgabe 1: Sättigungsmenge
Wenn der Preis sinkt, nimmt die Nachfrage normalerweise zu, bis man bei einem Preis p = 0 GE die Sättigungsmenge erreicht  (Snobeffekt: „Was nichts kostet, ist nichts wert!“).

Programmcode:

p(x):=0.11*x**2-1.5*x+4.39;
l:realroots(p(x)),numer;
xs:x,l[1];
xs:floor(xs*100+0.5)/100.0;

Erklärung:

  1. Gegeben ist eine quadratische Nachfragefunktion.
  2. Wenn der Preis Null ist, erhält man die Sättigungsmenge.
  3. Die quadratische Gleichung hat zwei Lösungen, die erste davon ist die Sättigungsmenge.
  4. Die Sättigungsmenge wird auf 2 Dezimalen gerundet.

Lösung mit Maxima Online:

Sättigungsmenge: http://maxima-online.org/?inc=r-1303960272
Mit Probe: http://maxima-online.org/?inc=r-1005449959

Zusatzaufgaben:

  1. Man zeichne die Nachfragefunktion mit Maxima.
  2. Man zeichne die Nachfragefunktion mit Geogebra.
  3. Man ermittle die Sättigungsmenge mit Geogebra.

Aufgabe 2: Preisobergrenze
Wenn der Preis zu hoch wird, sinkt die Nachfrage auf NULL.  Diese Preisobergrenze wird auch als Höchstpreis bezeichnet. Wir bestimmen zunächst eine quadratische Nachfragefunktion aus drei Punkten und berechnen dann die Preisobergrenze.

Programmcode:

Nachfrage:[[0,10],[4,3],[8,0]];
g(X):=X[2]=a*X[1]^2+b*X[1]+c;
g:map(g,Nachfrage);
l:solve(g,[a,b,c]);
p:a*x^2+b*x+c,l;
plot2d([p], [x,0,8]);

Lösung mit Maxima Online: http://maxima-online.org/?inc=r-551113382
mit Berechnung der Preisobergrenze: http://maxima-online.org/?inc=r-969524826

 

 

Trigonometrische Gleichung

Ausgangssituation auf GeoGebraTube: http://www.geogebratube.org/student/m91990

1.Aufgabe

Man kontrolliere die Lösung in der unveränderten Grundsituation mit Maxima. So geht es:

f(x):=sin(x);
g(x):=x-1.1;
plot2d([f(x),g(x)],[x,-5,5]);
Gleichung:f(x)=g(x);
x:find_root(Gleichung,x,-5,5);
y:g(x);
x:floor(x*100+0.5)/100.0;
y:floor(y*100+0.5)/100.0;
Loesung:[x,y];

Maxima Online: http://maxima-online.org/?inc=r-1394153949

Berechnungen mit Parabeln

Ausgangspunkt

Mit diesem Geogebraarbeitsblatt kann man zahlreiche Aufgaben generieren:http://geogebratube.org/student/m2840 (von John Golden)

Vertex ist der Scheitelpunkt der Parabel.

1. Aufgabe

Aufgabe1

Man bestimme die Gleichung dieser Parabel!

Die Lösung ist einfach, weil man drei Punkte leicht ablesen kann.

Programmcode

x1:0;y1:-4;
x2:4;y2:4;
x3:8;y3:-4;
Parabel:y=a*x^2+b*x+c;
g1:Parabel,x=x1,y=y1;
g2:Parabel,x=x2,y=y2;
g3:Parabel,x=x3,y=y3;
l:solve([g1,g2,g3],[a,b,c]);
Parabel,l;

Aufgabe 2

Aufgabe2

Man bestimmte die Fläche des eingeschriebenen Dreiecks. Kluge Köpfe vermögen die Lösung durch Kopfrechnen anzugeben. Es soll aber gezeigt werden, wie die Fläche aus den Eckpunkten bestimmt werden kann.

Programmcode

x1:0;y1:-4;
x2:4;y2:4;
x3:8;y3:-4;
a:sqrt((x3-x2)^2+(y3-y2)^2);
b:sqrt((x1-x3)^2+(y1-y3)^2);
c:sqrt((x2-x1)^2+(y2-y1)^2);
s:(a+b+c)/2;
F:sqrt(s*(s-a)*(s-b)*(s-c));

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r1218058705

Dreieck und Parabel

Aufgabe:

Man zeichne eine Parabel durch die Eckpunkte des Dreiecks
http://www.geogebratube.org/student/m89089 und kontrolliere die Gleichung der quadratischen Funktion.
Berechnung aus den drei Punkten mit (a) Maxima und b) Geogebra CAS.
Vereinbarung: Für verschiedene Aufgabestellungen darf NUR der Punkt C verändert werden.

Programmcode:

x1:0;y1:0;
x2:7;y2:0;
x3:4;y3:4;
g(x,y):=y=a*x^2+b*x+c;
g1:g(x1,y1);
g2:g(x2,y2);
g3:g(x3,y3);
l:solve([g1,g2,g3],[a,b,c]);
Parabel:g(x,y),l;

Berechnung der Parabel mit Maxima Onlinehttp://maxima-online.org/?inc=r282559695

Berechnung der Parabel mit Geogebra CAShttp://www.geogebratube.org/student/m89186

Teilebedarfsrechnung

Aufgabe:

teilebedarf

 

Grafische Darstellung:

teilebedarf1

Methode 1:

A: matrix(
[1,0,2],
[4,0,3],
[0,5,0]
);
B: matrix(
[6,3],
[2,4],
[0,5]
);
Output: matrix(
[100],
[200]
);
C:A.B;
Input:C.Output;

Abarbeitung mit Maxima Onlinehttp://maxima-online.org/?inc=r948162503

Methode 2:

g1:g=100;
g2:h=200;
g3:d=6*g+3*h;
g4:e=2*g+4*h;
g5:f=5*h;
g6:a=1*d+2*f;
g7:b=4*d+3*f;
g8:c=5*e;
l:solve([g1,g2,g3,g4,g5,g6,g7,g8],[a,b,c,d,e,f,g,h]);
Rohstoff_A:a,l;
Rohstoff_B:b,l;
Rohstoff_C:c,l;

Abarbeitung mit Maxima Online:  http://maxima-online.org/?inc=r-865495627

Eine Zusatzübung zum Probieren:

teilebedarf1

Schaltungen

Schaltpläne erstellen mit Geogebra-Tube: http://www.geogebratube.org/student/m2707

Wechselstromwiderstand (Serienschaltung) aus Geogebratube:
http://www.geogebratube.org/student/m6342

Wechselstromwiderstand (Parallelschaltung) aus Geogebratube:
http://www.geogebratube.org/student/m6344

Virtuelles Experiment der Universität Bayreuth:

http://virtphys.uni-bayreuth.de/elek/source/rserie.swf (geht nicht unter Android))

Ein Beispielprogramm (Serienschaltung von Widerständen):

U:5;
R1:430;
R2:180;
Rg:R1+R2;
g:I=U/Rg;
l:solve(g,I);
I:ev(I,l);
I:floor(I*1000+0.5)/1000.0;

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r480776298

Kurvendiskussion ist out!

Einleitung

Die klassische Form der Kurvendiskussions-Aufgaben ist als überholt anzusehen. Der Hauptzweck bestand zu meiner Schulzeit vor nahezu 50 Jahren ja darin, brauchbare Grundlagen für die Erstellung einer grafischen Darstellung zu bekommen.

Heute kann man z.B. eine grafische Darstellung vorgeben. Daraus können sich interessante Fragestellungen ergeben.

parabel

Aufgabe

  1. Man bestimme die Funktion, die die vorgelegte Grafik erzeugt.
  2. Man bestimme die Nullstellen.
  3. Man ermittle etwaige relativen Extremwerte.

Lösungsvarianten

Mit Geogebra ist die Aufgabe in kürzester Zeit erledigt, Aber MEISTENS unter Zuhilfenahme von „Black Box Methoden“!

Link zu Geogebra-Tube: http://www.geogebratube.org/student/m60359

Die Berechnung mit Maxima funktioniert ähnlich wie die Berechnung mit Papier und Bleistift!

Link zu Maxima Online: http://maxima-online.org/?inc=r1460096960