Kurvendiskussion

Aufgabe aus Geogebra-Tube: http://www.geogebratube.org/student/m59471

Gegeben sind also 4 Punkte:

A:[x=2,y=2];
B:[x=4.84,y=-0.4];
C:[x=7.68,y=2.3];
D:[x=11,y=0];

Lösung der Teilaufgabe (a): http://maxima-online.org/?inc=r1540912938

ratprint:false;
A:[x=2,y=2];
B:[x=4.84,y=-0.4];
C:[x=7.68,y=2.3];
D:[x=11,y=0];
g:y=a*x^3+b*x^2+c*x+d;
g1:g,A;
g2:g,B;
g3:g,C;
g4:g,D;
l:solve([g1,g2,g3,g4],[a,b,c,d]),numer;
koeff:[a,b,c,d],l;
koeff:floor(koeff*100+0.5)/100.0;
f:[x^3,x^2,x,1].koeff;

Lösung der Teilaufgabe (b):

Lösung der Teilaufgabe (c):

Lösung der Teilaufgabe (d):

Werbeanzeigen

Quadratische Funktion

Aufgabe:

aufgabe1

Anleitung zur Lösung:

  1. Man muss die Koordinaten der drei Punkte A, B, C in y=ax²+bx+c einsetzen. Dadurch erhält man drei Gleichungen mit den drei Unbekannten a,b und c. Wenn man das Gleichungssystem löst, erhält man a=1, b=-8 und c=15.
  2. A und B sind die Schnittpunkte mit der x-Achse. Da y=0 ist, nennt man sie Nullstellen. Manchmal gibt man unter dem Begriff Nullstellen nur die x-Werte an, da dort y=0 ist.
  3. Man muss die Gleichung x² -8x+15=0 lösen, nach der Mitternachtsformel („Große Lösungsformel für quadratische Gleichungen“).
  4. C ist ein Extremwert, und zwar ein Minimum.
  5. In einem Minimum gibt es eine horizontale Tangente, daher muss die erste Ableitung NULL sein. Die erste Ableitung ist nämlich die Steigung der Tangente. Wir müssen also die Gleichung 2x-8=0 lösen. Den zugehörigen y-Wert erhält man, indem man in die Funktions-Gleichung einsetzt.

Link zu Maxima Online: http://maxima-online.org/?inc=r221832178
„Klassische Lösung“: http://maxima-online.org/?inc=r-1817214728

Das ist eine Lösung mit viel Listenverarbeitung!
(%i1) Punkt:[[3,0],[4,-1],[5,0]];
(%o1)                     [[3, 0], [4, - 1], [5, 0]]
(%i2) g(x):=x[2]=a*x[1]^2+b*x[1]+c;
                                         2
(%o2)                    g(x) := x  = a x  + b x  + c
                                  2      1      1
(%i3) Gleichungen:map(g,Punkt);
(%o3)    [0 = c + 3 b + 9 a, - 1 = c + 4 b + 16 a, 0 = c + 5 b + 25 a]
(%i4) Unbekannte:[a,b,c];
(%o4)                              [a, b, c]
(%i5) Loesung:solve(Gleichungen,Unbekannte);
(%o5)                     [[a = 1, b = - 8, c = 15]]
(%i6) f(x):=a*x^2+b*x+c;
                                       2
(%o6)                       f(x) := a x  + b x + c
(%i7) ab:diff(f(x),x);
(%o7)                              2 a x + b
(%i8) Parabel:f(x),Loesung;
                                  2
(%o8)                            x  - 8 x + 15
(%i9) Ableitung:ab,Loesung;
(%o9)                               2 x - 8
(%i10) Nullstelle:realroots(Parabel);
(%o10)                          [x = 3, x = 5]
(%i11) y_Werte_NS:Parabel,Nullstelle;
(%o11)                                 0
(%i12) Extremwert:realroots(Ableitung);
(%o12)                              [x = 4]
(%i13) y_Werte_NS:Parabel,Extremwert;
(%o13)                                - 1
(%i14)

Schnittpunkte von Kreis und Hyperbel

Link zu Maxima Online: http://maxima-online.org/?inc=r777056383

Matthias Praunegger von Ping-Solutions und Desktop für Education hat mir eine verbesserte Version geschickt: http://maxima-online.org/?inc=r208949210

Wilhelm Haager auch weiter: „Das „Eiern“ kannst Du mit der (ziemlich neuen) Option ‚proportional_axes=xy‘ oder auf klassische Weise mit ‚user_preamble=“set size ratio -1″‚ wegbringen.“

Schnittpunkt von zwei Geraden: http://maxima-online.org/?inc=r-109813221

(%i1) "*"/* Schnittpunkt von Kreis und Hyperbel bestimmen */;
(%o1)                                  *
(%i2) load(draw);
(%o2)            /usr/share/maxima/5.21.1/share/draw/draw.lisp
(%i3) "*"/* Gleichung eines Kreises */;
(%o3)                                  *
(%i4) p1:x^2+y^2=4;
                                   2    2
(%o4)                             y  + x  = 4
(%i5) "*"/* Gleichung einer Hyperbel */;
(%o5)                                  *
(%i6) p2:x*y=1;
(%o6)                               x y = 1
(%i7) "*"/* Gleichungssystem lösen */;
res:solve([p1,p2],[x,y]),numer;
(%o7) [[x = - 1.931851652578137, y = - 0.51763809020504], 
[x = 1.931851652578137, y = 0.51763809020504], 
[x = - 0.51763809020504, y = - 1.931851652578136], 
[x = 0.51763809020504, y = 1.931851652578136]]
(%i8) "*"/* Schnittpunkte festhalten */;
(%o8)                                  *
(%i9) punkte:matrixmap(rhs,res);
(%o9) [[- 1.931851652578137, - 0.51763809020504], 
[1.931851652578137, 0.51763809020504], 
[- 0.51763809020504, - 1.931851652578136], 
[0.51763809020504, 1.931851652578136]]
(%i10) "*"/* Die graphische Darstellung der Lösung */;
(%o10)                                 *
(%i11) draw2d(color=black,implicit(p1,x,-3,3,y,-3,3),color=blue,
implicit(p2,x,-3,3,y,-3,3),color=red,point_type=7,point_size=2,
points(punkte),grid=true,xrange=[-3,3],yrange=[-3,3]);
(%o11) [gr2d(implicit, implicit, points)]
(%i12) draw2d(color=black,implicit(p1,x,-3,3,y,-3,3),color=blue,implicit(p2,x,-3,3,y,-3,3),color=red,point_type=7,point_size=2,points(punkte),grid=true,xrange=[-3,3],yrange=[-3,3]);;

Polynomgleichungen von W. Haager

Link zu Maxima-Online: http://maxima-online.org/?inc=r-1641098279
Eine Variante für Kreis und Hyperbel: http://maxima-online.org/?inc=r69798870

(%i1) load(draw);
(%o1) /usr/share/maxima/5.21.1/share/draw/draw.lisp
(%i2) p1:y^3+4*y^2+2*x*y+2*y+x^2+2*x=2;
                     3      2                  2
(%o2)               y  + 4 y  + 2 x y + 2 y + x  + 2 x = 2
(%i3) p2:13*x^2-3*y^2-20*x*y+20*y-26*x=-11;
                      2                       2
(%o3)            - 3 y  - 20 x y + 20 y + 13 x  - 26 x = - 11
(%i4) res:solve([p1,p2],[x,y]),realonly=true;
(%o4) [[x = - 14.07510729613734, y = - 8.988313856427379], 
[x = 1.38261253309797, y = - 2.538024164889837], 
[x = - 0.85062789160608, y = - 1.058122915674131], 
[x = 0.65693482761082, y = 0.070681797873291]]
(%i5) punkte:matrixmap(rhs,res);
(%o5) [[- 14.07510729613734, - 8.988313856427379], 
[1.38261253309797, - 2.538024164889837], 
[- 0.85062789160608, - 1.058122915674131], 
[0.65693482761082, 0.070681797873291]]
(%i6) draw2d(color=black,implicit(p1,x,-20,7,y,-10,2),         
color=blue,implicit(p2,x,-20,7,y,-10,2),         
color=red,point_type=7,point_size=2,points(punkte),
grid=true,xrange=[-20,7],yrange=[-10,2]);
(%o6)                 [gr2d(implicit, implicit, points)]
(%i7) draw2d(color=black,implicit(p1,x,-20,7,y,-10,2),         color=blue,implicit(p2,x,-20,7,y,-10,2),         color=red,point_type=7,point_size=2,points(punkte),grid=true,xrange=[-20,7],yrange=[-10,2]);;

Kleintierhaltung

Aufgabe:

In einem Stall gibt es Kaninchen (x) und Hühner (y).
Man zählt 20 Köpfe (k) und 56 Beine (b)

  1. Man berechne x und y.
  2. Welche anderen Vorgaben für k (Köpfe) und b (Beine) sind denkbar (bis zu einer gewissen Obergrenze)?

Programmcode für Teilaufgabe (1):

g1:x+y=20;
g2:4*x+2*y=56;
l:solve([g1,g2],[x,y]);

Maxima Online: http://maxima-online.org/?inc=r-295002031

Programmcode für Teilaufgabe (2):

Triviale Lösung mit Vielfachen (nun mit x Hühnern und y Kaninchen):

f(k,b):=solve([x+y=k,2*x+4*y=b],[x,y]);
f(20,56);
f(40,112);

Es scheint viele Lösungen zu geben: http://maxima-online.org/?inc=r1375203649
(das „ruft“ nach weiteren Untersuchungen).

 

 

Ziffernsumme einer dreistelligen Zahl

Eine Aufgabenstellung bei www.edhelper.com lautete in deutscher Übersetzung:
(g1) Die Ziffernsumme einer dreistelligen Zahl ist 18
(g2) Die Hunderterstelle ist um 6 größer als das 2fache der Zehnerstelle
(g3) Die Einerstelle ist um 6 größer als das 3fache der Zehnerstelle
Die dreistellige Zahl ist gesucht.

Programmcode:

g1:H+Z+E=18;
g2:H-6=2*Z;
g3:E-6=3*Z;
l:solve([g1,g2,g3],[H,Z,E]);
Zahl:100*H+10*Z+E,l;

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r-144388483

Übungsauftrag:

Zweiergruppen:
Formuliere derartige Aufgabenstellungen für frei gewählte dreistellige Zahlen (mit unterschiedlichen Ziffern).
Das andere Gruppenmitglied soll deine Aufgabenstellungen lösen.

Aufgabe für Fortgeschrittene:

Auch ohne Computer ist nicht schwer, herauszufinden, wie viele dreistellige Zahlen es gibt. Mit Computer ist es auch interessant: http://maxima-online.org/?inc=r-673670430 . Aber, wie viele dreistellige Zahlen mit unterschiedlichen Ziffern gibt es? Die Kombinatorik liefert schnell eine Antwort.
Ich hätte gerne, dass der Computer diese Zahlen aufschreibt.

Der Programmcode dazu:

H:setify(makelist(i,i,1,9));
Z:setify(makelist(i,i,0,9));
E:Z;
zahlenmenge:cartesian_product(H,Z,E);
zahlenliste:listify(zahlenmenge);
verschiedene_ziffern:sublist(zahlenliste,lambda([x],
cardinality(setify(x))=3));
length(verschiedene_ziffern);

Anmerkung: cardinality(M) ist die Mächtigkeit der Menge M. Die Mächtigkeit einer Menge, ist die Anzahl ihrer Elemente. Die Zahl 199 als Liste ist [1,9,9]. Wenn man die Liste zu einer Menge verwandelt, erhält man {1,9}. Da eine Menge eine Zusammenfassung von wohlunterschieden Objekten unserer Anschauung oder unseres Denkens ist, dürfen keine Ziffern mehrfach vorkommen. Die Umwandlung einer Liste x in eine Menge erfolgt mit setify(x).  Die lambda-Funktion berücksichtigt in der Teilliste (sublist) also nur dreistellige Zahlen mit lauter verschiedenen Ziffern.Liste_in_Menge_1

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r-1271358832

Es geht natürlich auch ohne Maxima:

Matthias Praunegger von http://www.d4e.at hat mir dieses Programm (mit einem anderen Algorithmus) geschickt:

matthias

 

Eine Kurvendiskussionsaufgabe mit Lösungen generieren

Aufgabe: Durch Veränderung der Eingabe kann man verschiedene Kurvendiskussionsaufgaben (mit den zu erwartenden Lösungen) generieren.

Maxima Online Programm dafür: http://maxima-online.org/?inc=r687730420

Die generierte Aufgabe soll mit Geogebra gelöst werden!

Hier die kontrollierte Grundaufgabe: http://www.geogebratube.org/student/m113304

Eine erste Übung dazu:

uebung

Und hier wird eine weitere Übungsaufgabe generiert:
http://maxima-online.org/?inc=r-611083516

Aufgaben zur Schaltung von Widerständen

Operatoren:

""/* SERIENSCHALTUNG */;
"~~"([x]):=xthru(apply("+",x));
nary("~~",110);

""/* PARALLELSCHALTUNG */;
"||"([x]):=xthru(1/apply("+",1/x));
nary("||",110);

1. Aufgabe: R1~~R2

serie

 

Anmerkung: Bei Serienschaltungen geht es auch ohne diese Operatoren, bei Parallelschaltungen und gemischten Schaltungen haben sie besondere Vorteile.

Programmcode:

""/* SERIENSCHALTUNG */;
"~~"([x]):=xthru(apply("+",x));
nary("~~",110);
Widerstand:[R1=100,R2=50];
Schaltung:R1~~R2;
Schaltung,Widerstand;

Maxima Onlinehttp://maxima-online.org/?inc=r662062382

2. Aufgabe: R1||R2

parallel

Programmcode:

""/* PARALLELSCHALTUNG */;
"||"([x]):=xthru(1/apply("+",1/x));
nary("||",110);
Widerstand:[R1=100,R2=100];
Schaltung:R1||R2;
Schaltung,Widerstand;

Maxima Onlinehttp://maxima-online.org/?inc=r583192055

 3. Aufgabe: (R1||R2)~~R3

gemischt

Programmcode:

""/* SERIENSCHALTUNG */;

"~~"([x]):=xthru(apply("+",x));
nary("~~",110);

""/* PARALLELSCHALTUNG */;

"||"([x]):=xthru(1/apply("+",1/x));
nary("||",110);

""/* GEMISCHTE AUFGABEN */;

Widerstand:[R1=100,R2=100,R3=200];
Schaltung:(R1||R2)~~R3;
Schaltung,Widerstand;

Maxima Onlinehttp://maxima-online.org/?inc=r1639710843