Nachfragefunktion bestimmen

Graphische Darstellung:

Image

Algorithmus:

x1:0;p1:5;
x2:8;p2:0;
g(x,p):=p=a*x+b;
g1:g(x1,p1);
g2:g(x2,p2);
l:solve([g1,g2],[a,b]);
Nachfrage:g(x,p),l;

Maxima Online: http://maxima-online.org/?inc=r-1366337180
PDF-Sicherung: r-1366337180

Der Algorithmus kann auch so formuliert werden:

P1:[x=0,p=5];
P2:[x=8,p=0];
g:p=a*x+b;
g1:g,P1;
g2:g,P2;
l:solve([g1,g2],[a,b]);
Nachfrage:g,l;

Maxima Online: http://maxima-online.org/?inc=r1427139021

Gewinnschwellen und Cournotscher Punkt

Ausgangslage: http://www.geogebratube.org/student/m64058
Interpretation: Grafische Darstellung einer quadratischen Erlösfunktion und einer quadratischen Kostenfunktion.

Was gibt es zu berechnen?

  • Die Erlösfunktion.
  • Die Kostenfunktion.
  • Die Gewinnfunktion.
  • Die Nachfragefunktion.

Erlösfunktion durch C,D und B und Nachfragefunktion mit Maxima Online: http://maxima-online.org/?inc=r-44669822

Kostenfunktion durch M,F und G mit Maxima Online:
http://maxima-online.org/?inc=r310156845

Grundlage für weitere Aufgaben sind die errechneten Erlös- und Kostenfunktionen:

  • E = -8/25 x² + 16/5 x
  • K = 8/105 x² + 4/105 x + 1

Gewinnzone mit Maxima Online: http://maxima-online.org/?inc=r1584557476
Cournotscher Punkt mit Maxima Online: http://maxima-online.org/?inc=r-970692400

Kosten- und Preistheorie

Aufgabe:

„*“/* Von einer Kostenfunktion ist folgendes bekannt: */;
„*“/* Die Fixkosten betragen 36 GE */;
„*“/* Bei einer Menge von x = 10 ME betragen die Gesamtkosten 216 GE */;
„*“/* Für x = 20 ME betragen die Gesamtkosten 596 GE */;
„*“/* Wie lautet die quadratische Kostenfunktion? */;
K(x):=a*x^2+b*x+c;
g1:K(0)=36;
g2:K(10)=216;
g3:K(20)=596;
l:solve([g1,g2,g3],[a,b,c]);
K:a*x^2+b*x+c,l /* errechnete Kostenfunktion */;

Kostenfunktion mit Maxima Online: http://maxima-online.org/?inc=r268861769

„*“/* Das Betriebsoptimum ist jene Produktionsmenge, bei der die */;
„*“/* Durchschnittskosten am kleinsten sind. */;
„*“/* So wird es berechnet: */;
ab:diff(K/x,x);
l:solve(ab=0,x);
BO:x,l[2];
„*“/* ALTERNATIVE Berechnungsmethode */;
l:solve(K/x=diff(K,x),x);
BO:x,l[2];

Betriebsoptimum mit Maxima Online: http://maxima-online.org/?inc=r1076321557

„*“/* Das Minimum der Durchschnittskosten (Stückkosten) */;
„*“/* ist die langfristige Preisuntergrenze. */;
„*“/* Wir berechnen diese: */;
LPU:K/x,x=BO;

Langfristige Preisuntergrenze mit Maxima Online:
http://maxima-online.org/?inc=r-645946022

Zum Thema Nachfragefunktion

Eine Nachfragefunktion beschreibt den Zusammenhang der nachgefragten Menge (abhängige Variable x) mit dem Preis (unabhängige Variable p). Es wird häufig das normale Nachfragegesetz unterstellt: steigt der Preis, sinkt die Nachfrage und umgekehrt. Eine bekannte Ausnahme ist der Snobeffekt. Die Nachfragefunktion entspricht (irgendwie) dem Verhalten der Konsument/inn/en.

Achtung: Normalerweise wird die unabhängige Variable auf der Abszissenachse und die abhängige Variable auf der Ordinatenachse abgetragen. Bei der Nachfragepunktion hat es sich in anders eingebürgert: p=p(x) statt x = x(p)

1. Aufgabe: Lineare Nachfragefunktion

Eine lineare Nachfragefunktion ist durch zwei Punkte gegeben.

nachfrage

Programcode:

x1:0;p1:5;
x2:10;p2:0;
g:p=a*x+b;
g1:g,x=x1,p=p1;
g2:g,x=x2,p=p2;
l:solve([g1,g2],[a,b]);
Nachfragefunktion:g,l;

Erklärung:

lf1

  1. Die Preisobergrenze (der Höchstpreis) ist 5 GE, da ist dann die Nachfrage auf 0 ME gesunken.
  2. Wenn man das Produkt verschenkt, werden 10 ME nachgefragt. Das ist die Sättigungsmenge.
  3. Ansatz für eine lineare Nachfragefunktion.
  4. Koordinaten des ersten Punktes einsetzen.
  5. Koordinaten des zweiten Punktes einsetzen.
  6. Das Gleichungssystem nach den unbekannten Koeffizienten auflösen.
  7. Die gefundenen Koeffizienten in die Nachfragefunktion einsetzen.

Ausführung mit Maxima Online: http://maxima-online.org/?inc=r701159078

2. Aufgabe: Lineare Nachfragefunktion

Die Marktforschung für eine Ware ergab, dass der
Monatsumsatz bei einem Verkaufspreis von p1 €
x1 ME, bei p2 € nur noch x2 ME betrug.
Wie groß ist der Absatz x3 bei einem Stückpreis
von p3 € ?

Programmcode:

p1:1;x1:1000;
p2:2;x2:900;
p3:3;
g(p,x):=p=a*x+b;
g1:g(p1,x1);
g2:g(p2,x2);
l:algsys([g1,g2],[a,b]);
A:a,l[1][1];
B:b,l[1][2];
Nachfrage:p=A*x+B;
g:solve(Nachfrage,x);
Absatz:x,g[1];
x3:ev(Absatz,p=p3);
print("Der gesuchte Absatz ist",x3);

 Lösung mit Maxima Online: http://maxima-online.org/?inc=r749682105

3. Aufgabe: Quadratische Nachfragefunktion

Von einer quadratischen Nachfragefunktion ist bekannt:

a) bei einem Preis von 3€ können 1000 Stück verkauft werden,
b) bei einem Preis von 1€ können 3000 Stück verkauft werden und
c) die Sättigungsmenge beträgt 5000 Stück!

Man ermittle diese Funktion und zeichne diese mit Geogebra!

Programmcode:

x1:1000$p1:3$
x2:3000$p2:1$
x3:5000$p3:0$
g(x,p):=p=a*x**2+b*x+c;
g1:g(x1,p1);
g2:g(x2,p2);
g3:g(x3,p3);
k:solve([g1,g2,g3],[a,b,c]);
Nachfrage:g(x,p),k;
p:rhs(Nachfrage);
p(x):=''p
/** Das ist die gesuchte Nachfragefunktion */;
plot2d([p(x)], [x,0,5200])$

Die „$“ Zeichen (Echo-Unterdrückung) sind nur in wxMaxima wirksam. Maxima Online macht „;“ daraus.

Ausführung mit Maxima Onlinehttp://maxima-online.org/?inc=r-1930608879

Die Funktion soll auch mit Geogebra gezeichnet werden!

S-förmiger Kostenverlauf

Begriffserklärung:
Eine Kostenfunktion stellt (innerhalb der Wirtschaftswissenschaften) eine eindeutige Zuordnung der Kosten K(x) zu einer Bezugsgröße x  dar.
Unsere Bezugsgröße ist meistens die Produktionsmenge in ME (Mengenheiten, z.B. Stück).
Ein s-förmiger Kostenverlauf (zuerst degressiv und nach der Kostenkehre progressiv) lässt sich aus dem Gesetz vom abnehmenden Grenzertrag herleiten. Die praktische Anwendbarkeit wird allerdings angezweifelt.

Ausgangssituation:

In den Mathematiklehrbüchern werden bei den Aufgaben der Kosten- und Preistheorie häufig Funktionen vorgegeben. Zur Theorie passende Funktionen muss man aber erst einmal finden.
Hier hilft Geogebra: http://www.geogebratube.org/student/m108070
Erklärung zur „Konstruktion“:sfkk_konstruktionDurch Ziehen an den Punkten kann man die Aufgabenstellungen einfach verändern.
Man kann die Geogebra-Datei für die lokale Verwendung herunterladen: http://www.geogebratube.org/material/download/format/file/id/108070

Aufgaben für die Lösung mit Maxima:

  1. Man bestimme die Kostenfunktion aus den Punkten A,B,C und D.
  2. Man bestimme die Fixkosten.
  3. Man bestimme die Kostenkehre.
  4. Man bestimme das Betriebsoptimum.
  5. Man bestimme die langfristige Preisuntergrenze.

Ein ungewöhnlicher Programmcode zur Bestimmung der Kostenfunktion:Berechnung von PolynomfunktionenWenn in Zeile (1) zwei Punkte gegebenen sind, erhält man eine lineare, bei drei Punkten eine quadratische und bei vier Punkten eine kubische Kostenfunktion. Um die kubische Kostenfunktion geht es beim s-förmigen Kostenverlauf.

Erklärung, wie das Programm Nr. 1 welches nicht nur für kubische, sondern auch für lineare und quadratische Kostenfunkitonen geeignet ist, funktioniert:

  1. Eingabe der gegebenen Punkte in Listenform.
  2. Da zwei, drei oder vier Punkte sinnvoll sein können, muss das Programm prüfen, wie viele Punkte gegeben sind.
  3. Der Grad des Polynoms ist um eins niedriger als die Anzahl der Punkte.
  4. Hier  wird ein raffinierter Ansatz verwendet.
    g(x) ist eine Funktion mit einem Punkt x:[x[1],x[2]] als Argument.
    Die Obergrenze der Summation muss n-1 = Grad und nicht n sein, da sonst der unbestimmte Fall 0^0 auftreten könnte. Dafür einfach a[n] ausserhalb hinzufügen.
  5. Die zwei, drei oder vier Gleichungen werden automatisch mit map erzeugt.
  6. Wie wir in (4) bemerkt haben, sind die unbekannten Koeffizienten nicht a,b,c,… sondern a[1],a[2],…,a[n].
  7. Die Lösungsmenge des Gleichungssystems wird ermittelt.
  8. Mit Hilfe der Skalarmultiplikation von Vektoren (Listen) wird die Kostenfunktion berechnet und ausgegeben.

Lösungen mit Maxima-Online unter Verwendung eines früheren Programms: https://casmaxima.wordpress.com/2014/04/08/ein-polynom-zur-einer-gegebenen-punkteliste-bestimmen/

  1. http://maxima-online.org/?inc=r-1197448632
  2. http://maxima-online.org/?inc=r-375516577
  3.  http://maxima-online.org/?inc=r-32032642
  4. http://maxima-online.org/?inc=r1686026510
  5. http://maxima-online.org/?inc=r1686026510